My 3 point dark strategy. WinCraps script help?

[raehn]

Hello all I am new to the forums but have been playing craps for a few years. (I just turned 26). I have a finance and account major so am attracted to gambling and numbers. I started playing basic count systems in blackjack but fell in love with craps and immediately started playing on the dark side and have done decently well for my bank roll. I usually start around $500 and cash out when I reach a 100% return. Currently I am up on Vegas about $6k so my luck has been decent. Truly I believe in math and know that I cannot win forever or even often and love to play around with spreadsheets using random number generators. I recently got into WinCraps but have not been successful with the scripts to make auto bets work for me.

I am curious if someone could help me write a script based on the way that I play just so while bored at work I can run some sessions.

My strategy (nothing special) is as follows:

Bet $5-$10 Don't Pass (depending on table min.) and take 3x odds.

Make 3 Don't Come Bet's with 3x odds as well.

Play until a 7 is thrown.

Occasionally I will do max odds on 4,10 but that is rare.

I think this is a fairly simple and easy strategy and is something of the opposite of the 3 way molly. I am not fully sure I haven't researched many strategies. I just made this one up while playing on my homemade table.

Even with math I am superstitious and I understand that tables fluctuate like a sin curve so if a shooter hits all 3 of my Don't Come's and the point I wait until he 7's out to bet anything else.

WinCraps Script request.

I am looking for someone to help me with a script. I want to buy in for $500 and end my session when I reach a 100% increase in profit so $1000 total bank. I want the script to auto bet a $5-10 don't pass with 3x odds followed by 3 don't come's with 3x odds. If an 11 is hit while betting the DC I wan't it to be put back up until 3 box numbers are up with the Don't Pass.

The part that I get stumped on in the script is how to make it stop betting a line bet and don't come bet once all my points have been taken down and to only re establish when the shooters 7's out (not on a come out roll).

If this is the wrong place to post I apologize.

Thanks!

[vegasfan2010]

I am not a darkside player. Good luck with your continued success.

The only thing I can comment on is trying for 100% profit. All profits are good. Maybe you should dial back your goal a bit. Close to double is great. One and a half times your buy in is okay, meaning 50% profit. Every time you leave the casino with some of their money is good.

Welcome to the forum.

[heavy]

You are in as good a place as any to post your request. I haven't looked at any Wincraps scripts in the last few years, so I'd have to noodle on it a bit. Hopefully one of the guys who dabbles with Wincraps more frequently than I do will help you out. Meanwhile, Steen does have a LOT of scripts already on the site that you can download and use. They are located here:

http://cloudcitysoftware.com/brfiles.htm

You might take a look at some of them and cobble something together from there. For the sake of simplicity I'd consider just setting it up with a $10 game with $30 odds regardless of the number rolled. $30 will work for any number. If you want to see how your results would have fared in a $5 game - just run the $10 script and cut the end results in half.

[SHOOTITALL]

Now also, the guy at wincraps does answer emails so if you cannot noodle it out, shoot him a email explaining what you want and he will tell you an answer. BTW: I sort of like that darkside three point molly. I would also try it out with a doey-don't to avoid the sheriff and his deputy

[Maddog]

This is probably pretty close (this is for wincraps-pro)... It does keep making DP's when a Pass is made. I would prefer to stop the DP until the next shooter and just play out any established DC, but for the hyperdrive I needed to have an active line-bet based on my settings.

Code: Select all

'-------------------------------------------------------------------------------
' Uses $10 as the betting unit
' For Each Shooter
' Make a Don't Pass bet and back with 3x Unit for odds (once point is set)
' -- any time shooter makes a pass, Stop betting, allow established DC to resolve
' -- start over on next shooter
' Make 3 successive Don't Come bets
' -- any DC that loses to an 11 natural, replace
' -- Lay 3x Unit as odds ($30)
' -- any DC that repeats, include as one of the successive 3 DC bets
' -- When 3 successive DC bets are made, quit betting until 7 out
'
'-------------------------------------------------------------------------------

If
   Initializing script :
Then
   Name CheckStack4 as "Count of DC Bets" :
   cs4.DC_Count = 0 :

   Name CheckStack3 as "# Times Busted" :
   cs3.Busted = 0 :

   Name CheckStack2 as "# Times Met 50% win goal" :
   cs2.MetWinGoal = 0 :

   AutoLay Full Odds = False :
   AutoHandle Winning Bets = 2 :
   ' -- setup our bankroll to $1000 per session
   If bankroll > $1000
   Then
      ATM deposit bankroll - 1000 :
   EndIf
   If
      bankroll < 1000 :
   Then
      ATM withdraw 1000 - bankroll :
   EndIf
EndIf

' ------------------------------------------------------------
' Keep track of each time we go bust or reach a 50% win goal
' reset the bankroll to $1000 on either condition
' - CheckStack#3 will keep a count of when we bust and go to the ATM
' - CheckStack#2 will keep a count of when we reach $1500 and deposit $500
'
If
   Available bankroll < $120 :
Then
   cs3.Busted = cs3.Busted + 1 :
   ATM withdraw 1000 - bankroll :
   'start new session(preserve checkstacks) :
   'cs4.DC_Count = 0 :
EndIf

If
   bankroll >= $1500 :
Then
   cs2.MetWinGoal = cs2.MetWinGoal + 1 :
   ATM deposit bankroll - 1000 :
   'start new session(preserve checkstacks) :
   'cs4.DC_Count = 0 :
EndIf


' ------------------------------------------------------------
' On new shooter make the Dont Pass bet
If
   New shooter :
Then
   '   Bet $10 on DontPass :
   cs4.DC_Count = 0 :
EndIf

' ------------------------------------------------------------
' because we are the only shooter, we make a DP on every new hand
' instead of waiting on a new shooter...
If
   Next roll is a comeout roll
Then
   Bet $10 on DontPass :
EndIf

' ------------------------------------------------------------
' Once a point is established, set our DP odds
' and begin making 3 Succesive Dont Come bets
' Replace eleven naturals
If
   a point is established
Then
   bet $30 on dontpassodds
   If
      cs4.DC_Count < 3 :
   Then
      Bet $10 on DontCome :
      cs4.DC_Count = cs4.DC_Count + 1 :
   EndIf
EndIf

If
   Dice total = 11
   And
   cs4.DC_Count >= 0 :
Then
   cs4.DC_Count = cs4.DC_Count - 1 :
EndIf

' ------------------------------------------------------------
' Set our specific lay-odds of 3 units
' might be a better way to do this using auto-play/config settings?
If
   DontCome4 :
Then
   DontComeOdds4 = $30
EndIf
If
   DontCome5 :
Then
   DontComeOdds5 = $30
EndIf
If
   DontCome6 :
Then
   DontComeOdds6 = $30
EndIf
If
   DontCome8 :
Then
   DontComeOdds8 = $30
EndIf
If
   DontCome9 :
Then
   DontComeOdds9 = $30
EndIf
If
   DontCome10 :
Then
   DontComeOdds10 = $30
EndIf

[al_falcons]

That is similiar to "Dave's System" and I have a couple of Win Craps Classic programs that I wrote that are close to what you are asking for. I will say one thing for your type of play based on my personal experience of the darkside play.
1. Having a win limit of 100% is hardly ever going to happen especially playing the dark side. Trying to double you money at any session at any casino game in my opinion is asking for big trouble and big losses. Try something like 20-30% would be more realistic.
2. The Don't come betting can be great when the table is cold, but a couple of hot shooters and you could lose 100-200 pretty quickly.
3. You would need to program something to limit how many DC bets you are going to make per shooter. How many times would you let your traveled DC bet get knocked off each time. If you don't limit that then 1 shooter could take your whole bankroll.

Send me a private message on this board with your email address and I will send you a couple of the scripts that I have written. I can't guarantee I will teach you how to write them, but it could get you started. You could also ask Steen questions about it too, if you have purchased a copy of WC.

[raehn]

Thanks for all of the replies! I will try Maddog's script when I get home and see if I cannot meddle around with it.

Basically I do know that doubling my money is quite the long shot and in live play I usually just try to hit around $200 profit in about a 1-2 hour time frame. That being said, as long as the first 2 or 3 shooters are cold I can survive the occasional hot shooter, even if he wipes out all of my active points. In trying this out over the last 21 (I know this is not a significant number) trips I have a win average of 5/6 to 1/6 loss. I have been counting wins as walking with over $200 and losses losing every last dollar. I have noticed that if the first or second shooter rolls more than 10 times which I believe is ~16% of shooters I will lose fast (obviously), meaning I either lose very quickly or am able to hold on until the table gets cold. I only need 3 or 4 cold shooters to walk away a winner. Also even if the first shooter is hot but isn't hitting my numbers I can hang on as well. I have had plenty of times where he establishes a 4 then hits a 9 and a bunch of 6's back to back before a 7.

[al_falcons]

Hey raehn any luck with the WinCraps testing? Just curious how it worked out.

[crapsjourney]

Hi all

Thought I'd test this strategy out.

Just learning WinCraps so made some small adjustments to the bet file.

The trend line on bankroll seems fairly flat on this strategy. I like the dark side, but I don't think this has enough positive bankroll motion, compared to other strategies.

Code: Select all

'-------------------------------------------------------------------------------
'As requested from APC Forum for user "raehn"
'https://axispowercraps.com/crapsforum/viewtopic.php?f=17&t=2405
'Thanks to Maddog for putting this together
'
' Uses $10 as the betting unit
' For Each Shooter
' Make a Don't Pass bet and back with 3x Unit for odds (once point is set)
' -- any time shooter makes a pass, Stop betting, allow established DC to resolve
' -- start over on next shooter
' Make 3 successive Don't Come bets
' -- any DC that loses to an 11 natural, replace
' -- Lay 3x Unit as odds ($30)
' -- any DC that repeats, include as one of the successive 3 DC bets
' -- When 3 successive DC bets are made, quit betting until 7 out
'
'-------------------------------------------------------------------------------

If
   Initializing script :
Then
   clear all(CheckStacks, CheckStackNames) :
   AutoHandle Losing bets = "No Bet/Take Remainder (if any)" :
   'Runtime settings
   AutoHandle Winning bets = "Take Bet and Winnings" :
   '   autotake full odds = true :
   '   autolay full odds = true :
   '*****
   'Debug Settings
   '   AutoHandle Winning bets = "Manual" :
   autotake full odds = false :
   autolay full odds = false :
   '*****


   Name CheckStack4 as "Count of DC Bets" :
   cs4.DC_Count = 0 :

   Name CheckStack3 as "# Times Busted" :
   cs3.Busted = 0 :

   Name CheckStack2 as "# Times Met 50% win goal" :
   cs2.MetWinGoal = 0 :

   Name CheckStack1 as "# Times DC beaten" :
   cs1.DC_LossCount = 0 :
   
   ' -- setup our bankroll to $1000 per session
   If bankroll > $1000
   Then
      ATM deposit bankroll - 1000 :
   EndIf
   If
      bankroll < 1000 :
   Then
      ATM withdraw 1000 - bankroll :
   EndIf
EndIf

' ------------------------------------------------------------
' Keep track of each time we go bust or reach a 50% win goal
' reset the bankroll to $1000 on either condition
' - CheckStack#3 will keep a count of when we bust and go to the ATM
' - CheckStack#2 will keep a count of when we reach $1250 and deposit $500
'
If
   Available bankroll < $120 :
Then
   cs3.Busted = cs3.Busted + 1 :
   ATM withdraw 1000 - bankroll :
   'start new session(preserve checkstacks) :
   'cs4.DC_Count = 0 :
EndIf

If
   bankroll >= $1250 :
Then
   cs2.MetWinGoal = cs2.MetWinGoal + 1 :
   ATM deposit bankroll - 1000 :
   'start new session(preserve checkstacks) :
   'cs4.DC_Count = 0 :
EndIf


' ------------------------------------------------------------
' On new shooter make the Dont Pass bet
If
   New shooter :
Then
   '   Bet $10 on DontPass :
   cs4.DC_Count = 0 :
   cs1.DC_LossCount = 0 :
EndIf

If
   dontpass loses
Then
   cs1.DC_LossCount = 1
EndIf

' ------------------------------------------------------------
' because we are the only shooter, we make a DP on every new hand
' instead of waiting on a new shooter...
If
   Next roll is a comeout roll
Then
   If
      'only process more bets if we haven't lost any previous DC or DP bets
      cs1.DC_LossCount = 0
   Then
      Bet $10 on DontPass :
   EndIf
EndIf

' ------------------------------------------------------------
' Once a point is established, set our DP odds
' and begin making 3 Succesive Dont Come bets
' Replace eleven naturals
If
   a point is established
Then
   
   If
      any(dontcome bets lose)
   Then
      cs1.DC_LossCount = 1
   EndIf
   
   If
      'only process more bets if we haven't lost any previous DC bets
      cs1.DC_LossCount = 0
   Then
      
      bet $30 on dontpassodds
      If
         cs4.DC_Count < 3 :
      Then
         Bet $10 on DontCome :
         cs4.DC_Count = cs4.DC_Count + 1 :
      EndIf
      
      If
         Dice total = 11
         And
         cs4.DC_Count >= 0 :
      Then
         cs4.DC_Count = cs4.DC_Count - 1 :
      EndIf
      
      ' ------------------------------------------------------------
      ' Set our specific lay-odds of 3 units
      ' might be a better way to do this using auto-play/config settings?
      If
         DontCome4 :
      Then
         DontComeOdds4 = $30
      EndIf
      If
         DontCome5 :
      Then
         DontComeOdds5 = $30
      EndIf
      If
         DontCome6 :
      Then
         DontComeOdds6 = $30
      EndIf
      If
         DontCome8 :
      Then
         DontComeOdds8 = $30
      EndIf
      If
         DontCome9 :
      Then
         DontComeOdds9 = $30
      EndIf
      If
         DontCome10 :
      Then
         DontComeOdds10 = $30
      EndIf
      
   EndIf
   
EndIf

'END

Bank roll image
http://i67.tinypic.com/oh2t3.jpg

[koreancowboy]

Reading the OP felt like I had wrote it LOL.

I play both Blackjack and craps, and I tried to do the same goal of doubling my bankroll in craps. Unfortunately, it doesn't work that way...I had to learn the hard way (after dropping $200 at the Palace on a $3 table, I turned around and made that back at a $5 single deck BJ table).

[heavy]

I think the breadth of bets available in craps causes a lot of folks from an advantage play blackjack point of view problems. At least that's part of it. In craps, at least from a DI point of view, there's so much more to it than just having an advantage - and there are so many things that can blow your advantage out the window. Something as simple as the dice hitting the chips, for example. Blackjack is much more of a fixed universe mathematically. The count is the count is the count, assuming you know how to count, and nothing the other players do at the table (at least on this hand) really impacts you - regardless of popular conjecture to the contrary. Of course, we went through this ad nauseum over on Wong's Green Chip board many years ago.

[mssthis1]

The count is the count is the count, assuming you know how to count, and nothing the other players do at the table (at least on this hand) really impacts you - regardless of popular conjecture to the contrary. Of course, we went through this ad nauseum over on Wong's Green Chip board many years ago.

I'm glad to see someone else who realizes this. I learned a long time ago to ignore how others are playing their hand. One of the best nights I ever had at a low limit BJ table was a night when the guy next to me was doubling on hard 12's, standing on 14 verses a 10 card and hitting 12's and 13's against a 6.

If someone asks me for advice on a hand I always tell them the book says to do so and so but it's your money so you do whatever you want.